shader_type canvas_item;

uniform vec4 old_palette[32];
uniform vec4 new_palette[32];
uniform int glowing[32];
const float pe = 0.004;

struct DyeResult{
	vec4 color;
	int index;
};

DyeResult dye(vec4 color){
	for(int i = 0; i<32; i++){
		if(distance(color, old_palette[i]) < pe){
			return DyeResult(new_palette[i], i);
		}
	}
	return DyeResult(color, -1);
}

vec4 rgb2hsv(vec4 inp){
	vec3 c = inp.rgb;
	vec4 K = vec4(0.0, -1.0 / 3.0, 2.0 / 3.0, -1.0);
	vec4 p = mix(vec4(c.bg, K.wz), vec4(c.gb, K.xy), step(c.b, c.g));
	vec4 q = mix(vec4(p.xyw, c.r), vec4(c.r, p.yzx), step(p.x, c.r));
	float d = q.x - min(q.w, q.y);
	float e = 1.0e-10;
	return vec4(abs(q.z + (q.w - q.y) / (6.0 * d + e)), d / (q.x + e), q.x, inp.a);
}

vec4 hsv2rgb(vec4 inp){
	vec3 c = inp.xyz;
	vec4 K = vec4(1.0, 2.0 / 3.0, 1.0 / 3.0, 3.0);
	vec3 p = abs(fract(c.xxx + K.xyz) * 6.0 - K.www);
	return vec4( c.z * mix(K.xxx, clamp(p - K.xxx, 0.0, 1.0), c.y), inp.a);
}

void fragment() {
	DyeResult dy = dye(texture(TEXTURE, UV));
	if(dy.index != -1 && glowing[dy.index] == 1){
		vec4 hsv = rgb2hsv(dy.color);
		hsv.z += sin(TIME*1.5)*0.1;
		COLOR = hsv2rgb(hsv);
	}
	else{
		COLOR = dy.color;
	}

}